ANSYS環境下全參數化建模分析,通過調整上下模參數使成型過程中不出現空隙.分三工步:上模快速下降,板料接觸下模后緩慢壓延,拔模回彈.

!!!!!!!!!板的沖壓仿真
FINISH
/CLEAR
*AFUN,DEG

X0=0
Y0=0
Z0=0

HBL=8
HXBL1=7.5
HXBL2=7.5
HYBL1=7.5
HYBL2=7

XBL1=25
XBL2=40
YBL1=28
YBL2=80

CE0=0.2

X1=XBL1
X101=X1+6
X201=X1+XBL2-11
X2=X1+XBL2
X4=200
X5=220

XCT1=X1+HXBL1
XCT101=XCT1+3
XCT2=X201-HXBL2+3
XCT201=XCT2+7
XCT3=XCT201+50

Y1=YBL1
Y2=Y1+10
Y3=YBL2
Y4=Y3+HBL+CE0+5
Y5=Y4+YBL1-(HBL*2-HYBL1-HYBL2)
Y6=Y4+YBL1+6
Y7=Y6+58

R01=10
R02=8
R03=10
R04=10
R05=13
SIT=50

RCT1=18
RCT2=5
RCT3=5
RCT4=20
X3=X2+(Y3-Y2)*COS(50)/SIN(50)

DY1=Y4-HBL
DY2=DY1+(HBL-HYBL2)+1
DY3=DY2-5

/PREP7
ET,1,182
KEYOPT,1,3,3

ET,2,169
ET,3,172
ET,4,169
ET,5,172
ET,6,169
ET,7,172

MP,EX,1,17000
MP,PRXY,1,0.3
TB,BKIN,1,1,2,1
TBTEMP,0.0
TBDATA,,30,0

MP,MU,2,0.2
MP,MU,3,0.2
MP,MU,4,0.2

R,1,2
R,2
R,2,,,0.3,0.1,0,
RMORE,,,1.0E20,0.0,1.0,
RMORE,0.0,0,1.0,,1.0,0.5
RMORE,0,1.0,1.0,0.0,,1.0
NROPT,UNSYM
KEYOPT,3,10,1

R,3
R,3,,,0.3,0.1,0,
RMORE,,,1.0E20,0.0,1.0,
RMORE,0.0,0,1.0,,1.0,0.5
RMORE,0,1.0,1.0,0.0,,1.0
NROPT,UNSYM
KEYOPT,3,10,1

R,4
R,4,,,0.3,0.1,0,
RMORE,,,1.0E20,0.0,1.0,
RMORE,0.0,0,1.0,,1.0,0.5
RMORE,0,1.0,1.0,0.0,,1.0
NROPT,UNSYM
KEYOPT,3,10,1

K,1,X0,Y1,Z0
K,2,X1,Y1,Z0
K,3,X101,Y0,Z0
K,4,X201,Y0,Z0
K,5,X2,Y2,Z0
K,6,X3,Y3,Z0
K,7,X5,Y3,Z0

L,1,2
L,2,3
L,3,4
L,4,5
L,5,6
L,6,7

LFILLT,1,2,R01
LFILLT,2,3,R05
LFILLT,3,4,R02
LFILLT,4,5,R03
LFILLT,5,6,R04

CM,TARBOT,LINE
NUMCMP,KP
LSEL,NONE

K,100,X3,Y3+HBL+CE0,Z0
K,101,X5,Y3+HBL+CE0,Z0
L,100,101
CM,TARTOP,LINE

NUMCMP,KP
NUMCMP,LINE
*GET,LMAXN,LINE,0,NUM,MAX

LSEL,NONE
K,100,X0,Y5,Z0
K,101,XCT1,Y5,Z0
K,102,XCT101,Y4,Z0
K,103,XCT2,Y4,Z0
K,104,XCT201,Y6,Z0
K,105,XCT3,Y7,Z0

L,100,101
L,101,102
L,102,103
L,103,104
L,104,105

LFILLT,LMAXN+1,LMAXN+2,RCT1
LFILLT,LMAXN+2,LMAXN+3,RCT2
LFILLT,LMAXN+3,LMAXN+4,RCT3
LFILLT,LMAXN+4,LMAXN+5,RCT4

CM,TARCT,LINE

NUMCMP,KP
K,100,100,150,Z0
K,101,100,160,Z0
K,102,100,170,Z0

LSEL,NONE
RECTNG,X0,X4,Y3,Y3+HBL
APLO
CM,ACONT,AREA
LSEL,S,LOC,Y,Y3
CM,LCONBOT,LINE
LSEL,S,LOC,Y,Y3+HBL
CM,LCONTOP,LINE

ALLSEL
LPLO

ESIZE,3,0,
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
NUMCMP,NODE

CMSEL,S,TARCT
TYPE,2
REAL,2
MAT,2
LMESH,ALL
KMESH,102
*GET,NCT,NODE,0,NUM,MAX

CMSEL,S,LCONTOP
NSLL,S,1
ESLN,S,0
TYPE,3
REAL,2
MAT,2
ESURF

CMSEL,S,TARTOP
TYPE,4
REAL,3
MAT,3
LMESH,ALL
KMESH,101
*GET,NTOP,NODE,0,NUM,MAX

CMSEL,S,LCONTOP
NSLL,S,1
ESLN,S,0
TYPE,5
REAL,3
MAT,3
ESURF

CMSEL,S,TARBOT
TYPE,6
REAL,4
MAT,4
LMESH,ALL
KMESH,100
*GET,NBOT,NODE,0,NUM,MAX

CMSEL,S,LCONBOT
NSLL,S,1
ESLN,S,0
TYPE,7
REAL,4
MAT,4
ESURF

CMSEL,S,TARBOT
NSLL,S,1
ESLN,S,1
ESURF,,REVERSE

ALLSEL
FINISH

/SOLU
ANTYPE,STATIC
NLGEOM,ON
RESCON,DEFINE,NONE
OUTRES,ALL,ALL
NSUBST,300,500,100
TIME,1

LSEL,S,LOC,X,X0
DL,ALL,,SYMM
D,NBOT,ALL
D,NTOP,ALL
D,NCT,,-DY1,,,,UY
ALLSEL
NPLO
EPLO
SOLVE

TIME,2
NSUBST,200,400,50
D,NCT,,-DY2,,,,UY
ALLSEL
SOLVE

TIME,3
NSUBST,200,400,50
D,NCT,,-DY3,,,,UY
ALLSEL
SOLVE
FINISH