ANSYS的log文件整理心得：解釋GUI中產生FLST和FITEM

2017-03-02 by:CAE仿真在線來源:互聯網

log文件整理心得
1.要注意時間,因為每次做的東西都會跟在log文件后面,所以要根據時間取舍,不是所有的log文件中的內容就有用的,一開始我建議從新建一個文件開始。
2.最好每做一步看一下log文件,可以知道自己的操作對應哪些命令
3.有些關于存盤、顯示視角等命令可以刪除。
4.選取實體時往往會產生很多命令,可以簡化。
5.整理命令流時要新建立一個文本文件,以便從log文件中拷貝所需要的。
6.File菜單中的Read input from可以讀入自己所建立的命令流來執行。
7.可以增加注釋語句以增強可讀性

下面以一簡單模型為例大致說明一下:

/BATCH
/COM,ANSYS RELEASE 5.7.1 UP20010418 15:42:42 09/12/2003
/input,menust,tmp ,'',,,,,,,,,,,,,,,,1
/GRA,POWER
/GST,ON
/PLO,INFO,3
/COL,PBAK,ON,1,BLUE
這一段基本上沒有用,是開始的設置,每個分析都是差不多這樣,因此可以刪除。

/PREP7
進入前處理器。在這一句前面可以加上fini /clear,這樣可以把模型原來的內容清空。

!*
ET,1,PLANE42
!*
定義單元
   
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,2e11
MPDATA,PRXY,1,,0.33
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,2700
定義材料類型

K,1,0,0,,
K,2,50,0,,
K,3,50,10,,
K,4,10,10,,
K,5,10,50,,
K,6,0,50,,
建立關鍵點

FLST,2,6,3
FITEM,2,1
FITEM,2,2
FITEM,2,3
FITEM,2,4
FITEM,2,5
FITEM,2,6
A,P51X
將幾個關鍵點連接成面
這里,關鍵點是通過鼠標選取而得到,因此命令較多,其實這一段可以改為,A,1,2,3,4,5,6,具體如何改寫可以參考FLST,FITEM命令的幫助

ESIZE,1,0,
設置單元大小

CM,_Y,AREA
ASEL, , , , 1
CM,_Y1,AREA
CHKMSH,'AREA'
CMSEL,S,_Y
!*
AMESH,_Y1
EPLOT
這一段的含義是對所選擇的面1進行網格劃分,可以改寫成AMESH,1。

FINISH
退出前處理器
/SOLU
進入求解器

FLST,2,1,4,ORDE,1
FITEM,2,5
!*
/GO
DL,P51X, ,ALL,
給選擇的線加位移約束。
可以改寫成:DL,5,,ALL

FLST,2,2,4,ORDE,2
FITEM,2,2
FITEM,2,-3
/GO
!*
SFL,P51X,PRES,1000,
給選擇的線加壓力
可以改寫成SFL,3,PRES,1000 SFL,2,PRES,1000

SOLVE
求解
FINISH
退出求解器

/POST1
進入后處理器
SET,FIRST
讀出第一個解集
PLNSOL,U,SUM,0,1
畫出節點位移解。

因此整理后的命令流文件如下:
fini
/clear
/PREP7

!定義單元
ET,1,PLANE42

!定義材料
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,2e11
MPDATA,PRXY,1,,0.33
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,2700

!建立模型
K,1,0,0,,
K,2,50,0,,
K,3,50,10,,
K,4,10,10,,
K,5,10,50,,
K,6,0,50,,
A,1,2,3,4,5,6,

!劃分網格
ESIZE,1,0,
AMESH,1

FINISH
/SOLU

!添加約束
DL,5,,ALL
SFL,3,PRES,1000
SFL,2,PRES,1000

SOLVE
FINISH

/POST1
SET,FIRST
PLNSOL,U,SUM,0,1

FLST 和 FITEM 是在 GUI 方式中,為某一命令選擇操作實體時產生的,反映在 log 文件中是一條 FLST 命令,跟著一條或幾條 FITEM 命令,再跟著一條帶有一個 P51X 的操作命令;

或者是一條 FLST 命令和若干條 FITEM 命令,跟著一條 FLST 命令和若干條 FITEM 命令,再跟著一條帶有兩個 P51X 的操作命令。

根據 ANSYS 的幫助文件,對 FLST 和 FITEM 的用法說明如下:

1 FLST 命令

FLST, NFIELD, NARG, TYPE, Otype, LENG

其中各參數說明如下:

NFIELD - 所選擇實體對應操作命令的第幾個參數 (field),注意操作命令的第一個域是命令本身,因此 NFIELD=2,表示是命令的第1個參數; NFIELD=3,表示是命令的第2個參數.....等。

NARG - 后續列表中的項數 (即后續 FITEM 命令行數)

TYPE - 所選擇的實體類型,定義為:
1 - 節點編號;
2 - 單元編號;
3 - Keypoint 編號;
4 - Line 編號;
5 - Area 編號;
6 - Volume 編號;
7 - Trace points;
8 - 總體直角坐標系中的坐標值;
9 - 屏幕坐標選擇 (在屏幕 X, Y 坐標中,值 (-1 to 1))

Otype - 數據排列方式,有兩種方式:
NOOR - 數據是無序的 (默認);
ORDER - 數據是個有序的表 (例如對于 E,P51X 和 A,P51X 命令,其中數據的順序與用 pick 方式選擇時的順序一致)。

LENG - 數據表長度 (后續 FITEM 命令的個數。如果 Otype = NOOR,LENG 應等于 NARG)

2 FITEM 命令

FITEM, NFIELD, ITEM, ITEMY, ITEMZ

其中各參數說明如下:

NFIELD - 所選擇實體對應操作命令的第幾個參數 (field),注意操作命令的第一個域是命令本身,因此 NFIELD=2,表示是命令的第1個參數; NFIELD=3,表示是命令的第2個參數;等。

ITEM - 所選擇實體的編號;負值表示它與上一個 FITEM 組成一個范圍,例如相連兩個 FITEM 的 ITEM 值分別為 4 和 -8,則表示 4,5,6,7,8 全被選中。

ITEMY, ITEMZ - 當所選實體為坐標值時,分別為 Y 和 Z 坐標,此時 ITEM 為 X 坐標。

注意:對于給定的實體類型,如果 ITEM 的值大于該類實體的最大值,可能導致不可預料的后果。